 MODEL:
! Model of a queuing system. A calling application passes
  the hourly server cost, lost customer cost, arriving customers
  per hour, and the average service time in minutes.  LINGO 
  returns the number of servers required to minimize total
  costs, which is the sum of the direct server costs and
  indirect costs of lost customers. 

! Minimize total cost = service costs + lost customer cost;
   [HourlyCost]  MIN = TotalServerCosts + TotalLostCustCosts;

! Cost of servers;
   TotalServerCosts = HourlyServerCost * ServersRequired;

! Cost of lost customers;
   TotalLostCustCosts = 
    CostPerLostCustomer * CustomerArrivalRate * 
     FracOfCustomersLost;

! The fraction of customers lost;
   FracOfCustomersLost = 
    @PEL( CustomerArrivalRate * MinutesToService / 60, 
     ServersRequired);

   @GIN( ServersRequired);

 DATA:
   HourlyServerCost = @POINTER( 1);
   CostPerLostCustomer = @POINTER( 2);
   CustomerArrivalRate = @POINTER( 3);
   MinutesToService = @POINTER( 4);
   @POINTER( 5) = ServersRequired;
   @POINTER( 6) = HourlyCost;
   @POINTER( 7) = FracOfCustomersLost;
   @POINTER( 8) = @STATUS();
 ENDDATA
 END 